TPW MODS: enhanced realism and immersion for Arma 3 SP.

[lordprimate 159]

aww you da man,  im just a dude... but i have to add make sure you remove the " - (4*night)"  fireflies will never spawn at night if you were to use that... i dont know why i left that in there it should be like "+ (2*night)" or something

[tpw 2314]

FIREFLY SCRIPT v3

 

OK so this is the final version that, barring a few refinements, will be packaged up into a mod this weekend. @Valken, this version now does pretty much everything you initially asked for. Sorry @lordprimate, I just can't deal with selectbestplaces, it's been annoying me ever since I tried using it in TPW ANIMALS years ago.  But the script does the next best thing in terms of placement and environmental sensing. I'm sticking to my guns and by default spawning bugs when there's at least a few trees/bushes around, but if you want fireflies out in the open away from trees then it can be easily set. I've incorporated the private variable changes to save a few ms too!

 

Using prerecorded flight paths for the fireflies works really well, looks authentic and consumes bugger all CPU. I tried an experiment with 500 fireflies around the player and dropped a couple of FPS max. It's also frees the script from dependence on the arcane ambient insect spawning system.

 

Anyway, here's the script if you'd like to try it:

/* 
TPW FIREFLIES
Adds animated lightpoints to simulate fireflies 
20161006
 
Thanks to Valken for the idea, lordprimate for input and suggestions
*/
 
// USER VARIABLES
tpw_firefly_active = 1; // Fireflies active. 0 = inactive
 
//Environment
tpw_firefly_window = 4; // How many hours after sunset will fireflies appear
tpw_firefly_temp = 18; // Minimum temperature (deg C) for fireflies to be active, if running TPW FOG
tpw_firefly_trees = 5 ; // Number of trees needed within tpw_firefly_radius of player in order to spawn fireflies. 0 = fireflies everywhere 
 
//Spawning 
tpw_firefly_radius = 25; // Firefies will be spawned within this distance (m) of player
tpw_firefly_time = 5; // Max seconds between spawning each firefly/swarm
tpw_firefly_maxflies = 50; // Maximum number of fireflies around player
tpw_firefly_swarmsize = 5; // Maximum number of fireflies per swarm (must be less than tpw_firefly_maxflies)
tpw_firefly_largeswarm = 0.1; // Chance of a swarm 5 times tpw_firefly_swarmsize spawning near player. 0 = never, 1 = always
 
// Firefly attributes
tpw_firefly_colour = [230,250,100]; // Firefly glow colour
tpw_firefly_brightness = 0.8; // Brightness of each firefly (0 - 1)
tpw_firefly_size = 0.05; //  Apparent size of each firefly (0.01 - 0.2)
tpw_firefly_blink = 1; // Flashing enabled. 0 = no flashing, 1 = brief flash with ~1 sec between flashes
tpw_firefly_speed = 0.075; // Max time (sec) between firefly animation "frames". Larger = slower moving fireflies
 
// CO-ORDINATES FOR ANIMATING FIREFLIES
tpw_firefly_flightarray = [[0.0439453,0.00634766,-0.0027256],[0.131836,0.0117188,-0.00764084],[0.216797,0.0117188,-0.0117626],[0.302734,-0.00244141,-0.0132179],[0.429688,-0.0385742,-0.0128517],[0.507813,-0.0749512,-0.0100594],[0.577148,-0.116211,-0.00601387],[0.666016,-0.195313,0.00541878],[0.708984,-0.256836,0.0153732],[0.761719,-0.358643,0.0343571],[0.786133,-0.427979,0.0485001],[0.796875,-0.500977,0.0638981],[0.797852,-0.616943,0.0920849],[0.787109,-0.689453,0.109226],[0.770508,-0.760742,0.123106],[0.734375,-0.871338,0.147993],[0.699219,-0.937744,0.162752],[0.661133,-1.00342,0.178305],[0.59082,-1.09888,0.20372],[0.533203,-1.15698,0.219051],[0.470703,-1.21118,0.236105],[0.370117,-1.28052,0.259731],[0.299805,-1.31787,0.273663],[0.222656,-1.35034,0.28941],[0.101563,-1.3833,0.309582],[0.0185547,-1.39478,0.323536],[-0.0644531,-1.40063,0.338097],[-0.141602,-1.39136,0.346508],[-0.253906,-1.36621,0.35914],[-0.326172,-1.33765,0.365284],[-0.388672,-1.30396,0.368486],[-0.477539,-1.23828,0.37532],[-0.524414,-1.18433,0.375397],[-0.567383,-1.12769,0.375376],[-0.621094,-1.0293,0.374701],[-0.641602,-0.964844,0.371052],[-0.655273,-0.897949,0.368309],[-0.663086,-0.797363,0.360992],[-0.65918,-0.730957,0.354088],[-0.648438,-0.664551,0.348282],[-0.618164,-0.565674,0.328905],[-0.59082,-0.50708,0.316721],[-0.561523,-0.449219,0.305183],[-0.50293,-0.375977,0.284504],[-0.456055,-0.329102,0.27211],[-0.401367,-0.260254,0.253872],[-0.376953,-0.215576,0.24193],[-0.359375,-0.172607,0.23156],[-0.348633,-0.108887,0.213509],[-0.353516,-0.065918,0.202593],[-0.364258,-0.0224609,0.193159],[-0.396484,0.0388184,0.181801],[-0.425781,0.0834961,0.17786],[-0.458984,0.126465,0.174463],[-0.524414,0.190674,0.1714],[-0.574219,0.233398,0.172075],[-0.626953,0.267822,0.173143],[-0.711914,0.312256,0.177267],[-0.775391,0.338379,0.182373],[-0.839844,0.352539,0.18766],[-0.943359,0.366455,0.199978],[-1.01465,0.366455,0.209566],[-1.08594,0.359375,0.219231],[-1.19336,0.33667,0.237915],[-1.26074,0.309326,0.249615],[-1.3291,0.277344,0.262356],[-1.42969,0.214355,0.284672],[-1.48926,0.162842,0.297728],[-1.54199,0.105469,0.312429],[-1.6084,0.0107422,0.331869],[-1.64258,-0.0559082,0.342173],[-1.66895,-0.128418,0.354151],[-1.69141,-0.239502,0.36729],[-1.69531,-0.313477,0.375938],[-1.69531,-0.385986,0.384855],[-1.67383,-0.485352,0.389666],[-1.64941,-0.551025,0.393681],[-1.61816,-0.613281,0.395206],[-1.58008,-0.668701,0.393782],[-1.51074,-0.743408,0.388815],[-1.45703,-0.783447,0.381929],[-1.40137,-0.819336,0.375084],[-1.30664,-0.865234,0.3643],[-1.24219,-0.883789,0.354816],[-1.17773,-0.896729,0.346823],[-1.07715,-0.904785,0.332701],[-1.00781,-0.900879,0.321283],[-0.939453,-0.889893,0.311756],[-0.844727,-0.857666,0.29425],[-0.787109,-0.829102,0.28429],[-0.730469,-0.797119,0.275248],[-0.658203,-0.732666,0.257126],[-0.614258,-0.683838,0.248888],[-0.553711,-0.594238,0.229216],[-0.533203,-0.553955,0.220648],[-0.501953,-0.480957,0.213087],[-0.483398,-0.429443,0.207119],[-0.46582,-0.391357,0.198231],[-0.435547,-0.360596,0.175703],[-0.412109,-0.348877,0.1598],[-0.385742,-0.350098,0.14596]];
 
// ANIMATE FIREFLIES
tpw_firefly_fnc_animate = 
{
private _fly = _this select 0;
private _model = _this select 1; 
private _startpos = visibleposition _fly; 
private _mult = 1 - (random 2); // random radius
private _sleep = tpw_firefly_speed/2 + random tpw_firefly_speed/2; // random speed
for "_i" from 0 to 100 do
{
_pos = tpw_firefly_flightarray select _i;
_fly setposatl (_startpos vectoradd (_pos vectormultiply _mult));
_model setposatl (_startpos vectoradd (_pos vectormultiply _mult));
sleep _sleep;
};
};
 
// SPAWN INDIVIDUAL FIREFLY AND BEHAVIOUR
tpw_firefly_fnc_spawnfly =
{
private _pos = (_this select 0) vectoradd [0,0,random 1];
 
// Create lightpoint
private _fly = "#lightpoint" createVehiclelocal _pos;  
private _model = "Mosquito" createvehicle _pos; 
_fly setLightColor tpw_firefly_colour;  
_fly setLightIntensity tpw_firefly_brightness; 
_fly setLightAttenuation [0,1,4,0,0.1,1];  
_fly setLightUseFlare true;
_fly setLightFlareSize tpw_firefly_size;
 
// Spawn behaviour for each lightpoint 
[_fly,_pos,_model] spawn 
{
private _fly = _this select 0;
private _pos = _this select 1;
private _model = _this select 2;
private _flash = 0.2 + (random 0.1);
private _dark = 1 + (random 0.5);
 
// Animation
[_fly,_model] spawn
{
private _fly = _this select 0;
private _model = _this select 1;
while {alive _fly} do
{
[_fly,_model] call tpw_firefly_fnc_animate;
};
};
 
// Lightpoint loop
while {alive _fly} do
{
// Activate light 
if (tpw_firefly_active == 1 && 
{rain < 0.2} && 
{windstr < 0.4}) then
{
if (tpw_firefly_blink == 1) then
{
// Blink
_fly setlightcolor tpw_firefly_colour;
_fly setlightintensity tpw_firefly_brightness - (random tpw_firefly_brightness / 2); 
sleep _flash;
_fly setlightintensity 0;
} else
{
// Steady
_fly setlightcolor tpw_firefly_colour;
_fly setlightintensity tpw_firefly_brightness - (random tpw_firefly_brightness / 2); 
};
} else
{
_fly setlightintensity 0;
}; 
 
// Delete if distant
if (_fly distance player > tpw_firefly_radius) then
{
deletevehicle _fly;
deletevehicle _model;
tpw_firefly_flycount = tpw_firefly_flycount - 1;
};
 
sleep _dark; 
};
};
tpw_firefly_flycount = tpw_firefly_flycount + 1;
_fly
};
 
// CONDITIONS FOR SPAWNING FIREFLIES
tpw_firefly_fnc_envscan =
{
while {true} do
{
// Warm enough? (TPW FOG)
private _temp = 1;
if !(isnil "tpw_fog_temp") then 
{
if (tpw_fog_temp < tpw_firefly_temp) then
{
_temp = 0;
} else
{
_temp = 1;
};
} else
{
_temp = 1;
};
 
// Conditions
if (tpw_firefly_active == 1 && 
{player == vehicle player} && // player on foot
{_temp == 1} && // warm enough
{daytime > tpw_firefly_dusktime && daytime < tpw_firefly_dusktime + tpw_firefly_window} && // night
{rain < 0.2} && // not raining
{windstr < 0.4} && // not windy
{count nearestTerrainObjects [player, ["tree","smalltree","bush"], tpw_firefly_radius, false] > tpw_firefly_trees}  && // sufficient trees
{nearestbuilding player  distance player > tpw_firefly_radius / 2} // no nearby buildings
) then
{
tpw_firefly_canspawn = 1;
} else
{
tpw_firefly_canspawn = 0;
};
sleep 10; 
};
}; 
 
// SPAWN FIREFLIES AROUND PLAYER 
tpw_firefly_fnc_spawnflies =
{
while {true} do
{
if (tpw_firefly_canspawn == 1 && {tpw_firefly_flycount < tpw_firefly_maxflies}) then
{
private _spawnpos = [player, tpw_firefly_radius] call cba_fnc_randpos;
private _swarmsize = tpw_firefly_swarmsize;
 
// Don't spawn on road or water
if (!(isonroad _spawnpos) && !(surfaceiswater _spawnpos)) then
{
// Occasional large swarm 
if (random 1 < tpw_firefly_largeswarm) then
{
_swarmsize = tpw_firefly_swarmsize * 5;
};
 
// Spawn swarm 
for "_i" from 0 to random _swarmsize do
{
[_spawnpos] call tpw_firefly_fnc_spawnfly;
sleep random 1;
}
}; 
}; 
sleep random tpw_firefly_time;
}; 
}; 
 
// RUN IT 
tpw_firefly_dusktime = ([] call BIS_fnc_sunriseSunsetTime) select 1;
tpw_firefly_flycount = 0;
tpw_firefly_canspawn = 0;
0 = [] spawn tpw_firefly_fnc_envscan;
0 = [] spawn tpw_firefly_fnc_spawnflies;
 

 

And the documentation:

TPW FIREFLIES - glowing animated ambient fireflies

 

Author: tpw

Thanks: Valken, LordPrimate

Requires: Community Base Addons for Arma 3

Compatibility: SP

 

Description

-----------

Fireflies are a widely appreciated feature during summer evenings in many parts of the world (but not mine unfortunately). Interestingly, Arma3 actually does spawn ambient fireflies at night, but they're not lit! To remedy this situation TPW FIREFLIES spawns animated lightpoints around the player which simulate the appearance and behaviour of swarming fireflies, which greatly adds to the visual ambience of playing on maps after sunset. 

 

Features

--------

By default TPW FIREFLIES spawns fireflies for four hours after sunset, if it's not too windy or raining, and the temperature is greater than 18degC. Fireflies will only spawn if there is sufficient vegetation and no nearby houses, and they won't spawn on roads or water. Fireflies will gradually spawn in, usually in small groups of 1 - 5 but occasionally in larger swarms of up to 25, up to a maximum of 50 fireflies within a 25 m radius of the player. The default firefly is green/yellow, briefly blinks on every second or so, and is bright enough to gently illuminate its surroundings within 0.5 m. 

 

TPW FIREFLIES is highly configurable: you can change the colour, size, speed and brightness (depending on the map and its night lighting config) of the fireflies; whether they blink or glow steadily; their number, density and swarm size; whether they spawn everywhere or only in dense forest; the temperature threshold for spawning; the time window after sunset; and the distance from the player they will appear/disappear. You can globally enable/disable TPW FIREFLIES using tpw_firefly_active at any time.  

 

// USER VARIABLES

tpw_firefly_active = 1; // Fireflies active. 0 = inactive

 

//Environment

tpw_firefly_window = 4; // How many hours after sunset will fireflies appear

tpw_firefly_temp = 18; // Minimum temperature for fireflies to be active, if running TPW FOG

tpw_firefly_trees = 5 ; // Number of trees needed within tpw_firefly_radius of player in order to spawn fireflies. 0 = fireflies everywhere 

 

//Spawning 

tpw_firefly_radius = 25; // Firefies will be spawned within this distance (m) of player

tpw_firefly_time = 5; // Max seconds between spawning each firefly/swarm

tpw_firefly_maxflies = 50; // Maximum number of fireflies around player

tpw_firefly_swarmsize = 5; // Maximum number of fireflies per swarm (must be less than tpw_firefly_maxflies)

tpw_firefly_largeswarm = 0.1; // Chance of a swarm 5 times tpw_firefly_swarmsize spawning near player. 0 = never, 1 = always

 

// Firefly attributes

tpw_firefly_colour = [230,250,100]; // Firefly glow colour

tpw_firefly_brightness = 0.4; // Brightness of each firefly (0 - 1)

tpw_firefly_size = 0.05; //  Apparent size of each firefly (0.01 - 0.2)

tpw_firefly_blink = 1; // Flashing enabled. 0 = no flashing, 1 = brief flash with ~1 sec between flashes

tpw_firefly_speed = 0.075; // Max time (sec) between firefly animation "frames". Larger = slower moving fireflies  

 

All of these variables may be changed on the fly in the debug shell or a trigger. For instance if you'd like the fireflies red, enter tpw_firefly_colour = [250,150,50] in the debug shell and the effect will be immediate. Or if you'd like a specific area of a map to have a higher density of fireflies you can place a trigger with tpw_firefly_maxflies = 200 in its On Activation field.

 

How it works

------------

In TPW FIREFLIES each firefly is represented by a lightpoint + the mosquito model texture. Plausibly animating the lightpoint in a CPU friendly way proved challenging, the solution was to record 5 seconds of flight of an ambient mosquito into an array of 3D co-ordinates, and step through the array, setting the position of the lightpoint/model to each co-ordinate. By varying the step speed and scaling the co-ordinates it's possible to achieve randomly flying fireflies that orbit a given point with constantly changing speed and radius. Because all flies use the same animation co-ordinates they occasionally sync up and give every appearance of interacting in the swarm. The process uses simple fast vector functions and consumes very little CPU, with dozens or even hundreds of fireflies present.  

 

Issues

------

TPW FIREFLIES came about from a request from Valken to enliven the nightime in jungle maps such as Tanoa. My initial attempts attaching/moving lightpoints to existing ambient insects worked OK but after a bit of feedback and youtube research I realised that a more customisable solution was required to achieve a more believable firefly experience. It's been an enjoyable challenge to come up with the current implementation of TPW FIREFLIES. I should stress that it's not within the scope of this mod to fully simulate the biology and complex behaviour of a diverse group of insects. However you should be able to customise the experience to suit your own expectations of plausibility. If you want giant bright blue fireflies blanketing the area for 100 m around the player on your sci-fi map, then knock yourself out. There are no fireflies on Fiji, but neither are there kookaburras, but now you can have both on Tanoa! 

 

Although TPW FIREFLIES uses very little CPU to do its thing, the fireflies are dynamic lights and having lots of them in an area can cause the engine to flip out a bit. You might occasionally notice flickering house or street lights when numerous fireflies are about, or fireflies with a light flare but no illumination, or invisible fireflies with no flare that still illuminate the surroundings. Caveat emptor!

[lordprimate 159]

it might seem arcane, however, that was what killed it for me ... they were bugs with lights not just flashing lights.. when you put on your nvg's you saw the bugs flying around. and then they would light up. (sick just sick).. . i have Not yet had a chance to test, its late and am passing out.. just looking around and saw your post.. i hope you didnt remove the lights from the spawned bugs completely? if so can you make it an option ( agian i havent looked to see if you had arleady) sorry. i honestly didnt like the cluster of flashing lights with No actual bugs to see.  i dont see any calls in the script for the firefly.jpg. so im assming not. man that was fucking awesome seeing the bugs flying around then flashing ... was serene... if its possible can you use the firefly texture attached to your light emmiter? what would be tits.... and its all good about that script snibbit.. was just an idea!! 

[tpw 2314]

it might seem arcane, however, that was what killed it for me ... they were bugs with lights not just flashing lights.. when you put on your nvg's you saw the bugs flying around. and then they would light up. (sick just sick).. . i have Not yet had a chance to test, its late and am passing out.. just looking around and saw your post.. i hope you didnt remove the lights from the spawned bugs completely? if so can you make it an option ( agian i havent looked to see if you had arleady) sorry. i honestly didnt like the cluster of flashing lights with No actual bugs to see.  i dont see any calls in the script for the firefly.jpg. so im assming not. man that was fucking awesome seeing the bugs flying around then flashing ... was serene... if its possible can you use the firefly texture attached to your light emmiter? what would be tits.... and its all good about that script snibbit.. was just an idea!! 

No worries LP, I didn't realise it troubled you so! I've attached the Mosquito model to the lightpoints for all your visible insect needs. There's no Firefly model. I updated the script and docs in my post above.

[Valken 621]

@ TPW - Still playing around with the settings and colors but WOW! Thank You!

 

[Leopard20 813]

I like every thing about this mod except one thing: slow animations (movement and stance).

I know your focus has been on making the game more realistic but you must admit that people demonstrate extreme and superhuman abilities when in extreme circumstances. So it's not surprising seeing a soldier running at full speed to save his dear life. That and the fact that ARMA is already a slow-paced shooter make this feature (slow animations) seem all the more redundant.

Can you separate the animation mod from others as a pbo, or at least put the corresponding setting in the config file? This way we have a choice as to whether we want it or not.

[tpw 2314]

Can you separate the animation mod from others as a pbo, or at least put the corresponding setting in the config file? This way we have a choice as to whether we want it or not.

It already is, just delete the cryptically named tpw_animspeed.pbo if the transitions upset you so much. Or edit these cleverly hidden entries at the bottom of the tpw_mods.hpp :

 

//animationsActivePlaceholder = 1;
#define run_rifle 0.6 //default 0.685
#define tactical_rifleup 0.7 //default 0.786
#define tactical_jog 1.35 //default 1.55
#define unarmed_walkspeed 0.27 //default 0.35
#define rifledown_walkspeed 0.20 //default 0.3
#define rifleup_walkspeed 0.80 //default 0.85
#define roll_left 0.6 //default 1.1 
#define roll_right 0.7 //default 1.2//>< 

[Leopard20 813]

 

It already is, just delete the cryptically named tpw_animspeed.pbo if the transitions upset you so much. Or edit these cleverly hidden entries at the bottom of the tpw_mods.hpp :

 

//animationsActivePlaceholder = 1;
#define run_rifle 0.6 //default 0.685
#define tactical_rifleup 0.7 //default 0.786
#define tactical_jog 1.35 //default 1.55
#define unarmed_walkspeed 0.27 //default 0.35
#define rifledown_walkspeed 0.20 //default 0.3
#define rifleup_walkspeed 0.80 //default 0.85
#define roll_left 0.6 //default 1.1 
#define roll_right 0.7 //default 1.2//>< 

 

Silly me. I think I misread animspeed as "animalspeed" when I was looking in the addon folder! LOL

[tpw 2314]

TPW MODS 20161008: https://dl.dropboxusercontent.com/u/481663/TPW_MODS_20161008.zip

 

Changes:

• [HPP update required]
• [FIREFLIES 1.00] New mod, adds glowing animated fireflies on warm evenings for some extra nighttime ambience.

---

As threatened, fireflies has been released as its own mod, for all your luciferase illumination needs. Documentation here.

[Biflioi 8]

awesome!!! just in time for a nice weekend session  :wub:  

[Valken 621]

Weekend is here so more testing will resume! Thanks TPW!

 

@ TPW - A question for skirmish. Is it possible to use wildcards in the unit selection? EG if I want to select a subset of units from a mod but that subgroup is defined with a suffix at the end of the unit names such as TROPIC or BLACK, can I do with the following code:

 

  "opfor_*_tropic" or "opfor_*_black"

 

Some mods just append the description at the end of a very long classname to separate it into groups instead of a prefix such as opfor_tropic_xxx where XXX would be the actual class.

 

It is hard to select the units this way if they use a suffix.

[sonsalt6 105]

Updated mod v2016.10.1 available at withSIX. Download now by clicking:

[Happiness33JMP 1]

Hello, I have a problem I do not want friction on civilians, cars, helicopters. I just infantry realism. Example 1-0 AIR = inactive. Doesnt work for me. Or How can I remove things that I do not? Thank you.

[Guest]

New version frontpaged on the Armaholic homepage.

 

TPW MODS v20161008

Community Base addons A3

[taro8 806]

I would like to add a delay between unit being spotted byt TPW HUD and marker being drawn. I feel that reported units should be marked immediately, but units that are just seen by HUD should have a delay before being marked, preferably if the delay could changed from the userconfig, but since I remove the "%1s" and "1%s 2%m" at each update I'll with editing the script itself.

 

Oh, also a delay on removing markers from dead units would nice, this could make the HUD a bit less of a cheat.

[denison10 0]

@tpw

 

I offer to do the activation of HUD in the vehicle, air vehicle and the use of drones in time.

[tpw 2314]

Thanks for the last few days of input people. Sorry I did not address them sooner, I've just been made redundant at work so have bigger fish to fry. I will get onto this stuff when things settle down. Thanks for your patience and understanding

[domokun 515]

Thanks for the last few days of input people. Sorry I did not address them sooner, I've just been made redundant at work so have bigger fish to fry. I will get onto this stuff when things settle down. Thanks for your patience and understanding

I'm sad to hear that. Short-term it'll be tough but (fingers crossed) it'll be better for you in the long-term. Best of luck with your job hunting.

[kremator 1064]

Sorry to hear that tpw.  Best of luck mate!

[Zakuaz 195]

Love this mod set TPW, thanks for all the hard work and a big thanks to bringing my ARMA experience to life.

 

I am trying to ween myself off of those damn tactical glasses but the idea/useage of them as I roll around pretending to be the Hi-end Operator fits right in.   They are just so effective.

 

They have surely allowed me to stay alive on my missions and I'd like to and will continue to use them but I had an idea.

 

Would it be possible to have the on screen enemy markers pulse on and off at a desired/adjustable rate?

 

Here is my dorky story behind it.

 In an effort to make my glasses not feel so OP I can only use them when I have a darter UAV set to follow me - ok so yeah that means I pretty much always have a UAV hovering over me at 200 heh. My situational enhancement network - dorking out here...- would be really cool if I could de-tune it a bit.  Having a setting in the hpp (IIRC that is where I adjust various values for the mods, don't quote me) file to change the rate at which the on screen enemy markers pulse in and out of view would be cool, I could set it to once every 5 seconds ( that'd get annoying) or take it out to once a minute or more.

 

Again thank you for the work you've put in man, the game wouldnt be the same with out TPW.

Sorry to hear about the bump in your road, hope all works out well into your favor.

[tortuosit 485]

Hi TPW or anybody else, I always spawned a battlefield via script call. Like this: should also run from debug window:

0 = [] execvm "\@tpw_mods\scripts\tpw_core.sqf";
0 = [9,3,9,3,3,1,400,2000,1,1,1,20,"str1","str2","str3","str4"] execvm "\@tpw_mods\scripts\tpw_skirmish.sqf";

But recently I receive errors. Undefined variable in tpw_core line 146.

[Jimmakos 168]

Should be:

0 = [[]] execVM "\@tpw_mods\scripts\tpw_core.sqf";

[pvt. partz 248]

Hello TPW

 

    Here is idea number,..............ah shti who's counting.

 

If the wind speed exceeds, oh say 10 or 15 mph, create a falling leaf cluster around the player when near deciduous trees. I was thinking the other day, if they can make butterflies and bugs, zig zag around randomly, I was thinking a couple of different leaves could be made to float to the ground.

   I'll check back in an hour and see what you've come with!!! :D 

[Deathrow Bo Dean 4]

!Hello TPW, I've downloaded and installed Your Mod so I guess it will work ok. I just need at this time to dress up my SP Stratis SP mission with some civilians, I don't wish them to do any fighting. I just want them for to be hostages in or near a building on the Stratis main airbase.

My problem is that:  I can't find a simple tutorial about just how to use a TPW MOD.,  I'm new to Arma 3 with a Steam install. I'd like to find or get a simple step by step  tutorial that will teach me how to use Your TPW Mod or Mods. I'm not a scriptor or programmer I'm just a server operator. I'm still a bit uneasy placing scripts in the init in the Eden Editor but i can follow simple directions. .Please help........DBD.... 

[tpw 2314]

Hi all

 

Firstly, thanks for the kind wishes, I appreciate them greatly.

 

Just to let you know that I haven't abandoned my A3 modding, coding helps take my mind off reality especially when reality is shit. I've been trickling along with a few HUD and SKIRMISH ideas in response to some of the suggestions. No falling leaves as yet Pvt Partz!

 

Deathrow Bo Dean, what makes you think I'd release TPW MODS with no instructions how to use it?!? Please have a look at the bottom of the the first post under Documentation. Specifically 

• Full readme with installation and usage instructions