How to? Eject AI

[Earacorn 1]

I'm looking for a script so I can have enemy divers eject over water.. Does anyone know how to do this? I've seen a few for arma 2 but I'm just not sure if they will work like I want.. I'll try them in the meantime I guess.

[cobra4v320 27]

Look up the ARMA 2 command "action"

[Earacorn 1]

It accepts the script but I still cant seem to get the heli to drop the divers while he is hovering over water.. I also need to get the heli to come down in altitude just a bit so the divers don't just jump to their deaths.

[cobra4v320 27]

Check out my last post on this thread, it still needs some work though.

http://forums.bistudio.com/showthread.php?149837-Dynamic-Dive-Team-Script

[Earacorn 1]

Holy crap this is way over my head lol... I'll see what I can learn. I'll probably come back to this tomorrow my brain is scripted out. Thx for all the help Cobra :D

[cobra4v320 27]

Just start with this and experiment. Place it into a file and call it diveteam.sqf

Create your init.sqf and put this into it: [getmarkerpos "start",player] execVM "diveteam.sqf" or you can do a radio trigger to test.

Create a marker named start and place your player out into the water.

Start your mission and a helicopter should spawn in, fly to your position, fly to a height of 5 meters, than drop of 4 divers, the helicopter will then fly back to its starting point, and the divers will just be sitting in the water.

_start = _this select 0;
_target = _this select 1;

//if the target is not on water cancel the mission
if (!surfaceIsWater position _target) exitWith {hint "The target is on dry land."}; //for testing?

//create helicopter
_grp_heli = creategroup East;
_heliSpawn = [_Start, 180, "O_Ka60_F", _grp_heli] call bis_fnc_spawnvehicle;
_heli = _heliSpawn select 0;

//create dive team
_grp_diver = [_start, EAST, (configFile >> "CfgGroups" >> "East" >> "OPF_F" >> "SpecOps" >> "OI_diverTeam")] call BIS_fnc_spawnGroup;
_grpLeader = leader _grp_diver;

//assign dive team to helicopter and move in cargo
{_x assignasCargo _heli; _x moveinCargo _heli} foreach (units _grp_diver);

//create helicopter waypoint to target and its behavior
_grp_heli Move position _target;
_grp_heli setSpeedMode "FULL";
_grp_heli setBehaviour "SAFE";
_grp_heli setCombatMode "BLUE";

//wait until helicopter is near target and at 5 meters above sea level before dropping off divers
waitUntil {_heli distance _target < 150};
_heli flyinheight 5;
Waituntil {(getPosASLW _heli select 2) < 5};

//eject divers one at a time for every half second
sleep (random 3);
{unassignVehicle (_x);(_x) action ["EJECT", vehicle _x]; sleep 0.5} foreach (units _grp_diver);
waitUntil {{_x in _heli} count (units _grp_diver) == 0};
sleep 3; // added to keep the helicopter hovering for a couple seconds while divers enter the water

//move helicopter back to its starting position
_heli flyinHeight 40;
_heli doMove (_start);

Edited March 17, 2013 by cobra4v320

[curtcooll 1]

There 2 ways it can be done one with waypoints and like the above script i spent a few hours on ejecting divers and worked it out perfect.

[cobra4v320 27]

Im working on a diver insertion script for boats and helicopters.

[Earacorn 1]

Just start with this and experiment. Place it into a file and call it diveteam.sqf

Create your init.sqf and put this into it: [getmarkerpos "start",player] execVM "diveteam.sqf" or you can do a radio trigger to test.

Create a marker named start and place your player out into the water.

Start your mission and a helicopter should spawn in, fly to your position, fly to a height of 5 meters, than drop of 4 divers, the helicopter will then fly back to its starting point, and the divers will just be sitting in the water.

_start = _this select 0;
_target = _this select 1;

//if the target is not on water cancel the mission
if (!surfaceIsWater position _target) exitWith {hint "The target is on dry land."}; //for testing?

//create helicopter
_grp_heli = creategroup East;
_heliSpawn = [_Start, 180, "O_Ka60_F", _grp_heli] call bis_fnc_spawnvehicle;
_heli = _heliSpawn select 0;

//create dive team
_grp_diver = [_start, EAST, (configFile >> "CfgGroups" >> "East" >> "OPF_F" >> "SpecOps" >> "OI_diverTeam")] call BIS_fnc_spawnGroup;
_grpLeader = leader _grp_diver;

//assign dive team to helicopter and move in cargo
{_x assignasCargo _heli; _x moveinCargo _heli} foreach (units _grp_diver);

//create helicopter waypoint to target and its behavior
_grp_heli Move position _target;
_grp_heli setSpeedMode "FULL";
_grp_heli setBehaviour "SAFE";
_grp_heli setCombatMode "BLUE";

//wait until helicopter is near target and at 5 meters above sea level before dropping off divers
waitUntil {_heli distance _target < 150};
_heli flyinheight 5;
Waituntil {(getPosASLW _heli select 2) < 5};

//eject divers one at a time for every half second
sleep (random 3);
{unassignVehicle (_x);(_x) action ["EJECT", vehicle _x]; sleep 0.5} foreach (units _grp_diver);
waitUntil {{_x in _heli} count (units _grp_diver) == 0};
sleep 3; // added to keep the helicopter hovering for a couple seconds while divers enter the water

//move helicopter back to its starting position
_heli flyinHeight 40;
_heli doMove (_start);

Ok.. here's the thing, I've never done any scripting or editing out of the game everything up until this point has been done in game with the initialization thing... So when you say create diveteam.sqf and init.sqf are those just notepads that I copy all of that text into and just put into my mpmissions folder? Or is there something I'm missing here? Sorry I know this is a pain.

[cobra4v320 27]

Here is an example mission with a boat insertion and helicopter insertion. These are a WIP, feedback is welcome.

Execute: null = [getmarkerpos "start",player, east] execVM "dynDiverBoat.sqf" or null = [getmarkerpos "start",player, east] execVM "dynDiverHeli.sqf"

http://rapidshare.com/files/4109608984/Dynamic_Diver.zip

[Earacorn 1]

lol.. again you kinda left me in the dust.. I haven't done any work with radio yet.. Am I supposed to somehow radio Alpha or bravo?

[cobra4v320 27]

Use the radio 0-0-1 and 0-0-2 to test.

[Earacorn 1]

Yea thats exactly what I was looking for. Do you mind if I use this in my mission? If I post it I'll give you credit.

[cobra4v320 27]

Go for it