Results 1 to 10 of 10

Thread: Radio Chat Module, how to make it work?

  1. #1

    Radio Chat Module, how to make it work?

    Seems like they added a module to do Radio chat now.

    What i've done is to create a trigger, and then sync it to the Radio Chat, so it starts when im in the trigger area. Problem is that i want another player to "Text the message" rather than the one reaches the trigger first. Right now it says "Alpha 1-1 (My name): Hi, this is the text" but i want it for the mission to be something like "Commander: Hi, this is the name i want to be displayed instead".

    Any ideas?
    Computer Spec Intel 3570K | 8 Gb Ram | GTX660 TI

  2. #2
    I'd suggest creating a GameLogic and having it speak GlobalChat. For example:

    Code:
    myGameLogic GlobalChat "Commander: Hello"
    Will simply display "Commander: Hello". It doesn't show any "Alpha 1-1" stuff, so you can type in whatever speaker name you like.

    Sadly I think it works only with GlobalChat and not SideChat.

    You may want to also read this related thread.

  3. #3
    I tried to use the radio chat module (F7+Event), but I dont understand how to use it. Any ideas?
    www.combatetatico.com.br

    Core i7-4770K - MSI-GD65 - ASUS HD 7970 DCU2-TOP - 12GB

  4. #4
    Place the module down.
    Set Apply To to: Synchronized group (oops!)
    Set Text to: Whatever text you want to be displayed.
    Set Channel to: Whichever channel you want the text to be displayed on. Note vehicle only displays if you're inside a vehicle.

    Place down a trigger with whatever activation and area you want.

    Synchronize the trigger and module.

    Activate the trigger and enjoy the text messages.
    Last edited by kylania; Sep 14 2013 at 13:41.

  5. #5
    Quote Originally Posted by kylania View Post
    Place the module down.
    Set Apply To to: Objects in synchronized trigger
    Set Text to: Whatever text you want to be displayed.
    Set Channel to: Whichever channel you want the text to be displayed on. Note vehicle only displays if you're inside a vehicle.

    Place down a trigger with whatever activation and area you want.

    Synchronize the trigger and module.

    Activate the trigger and enjoy the text messages.
    Thx Kylania master, but, I already tested this way, is failing, the event don't start, or start and the module fail..... =(

  6. #6
    Works for me. Check your trigger condition is correct.

    If you want to have two or more units having a radio conversation though, it would be far easier to use a script or even straight in a trigger activation like this:

    Code:
    0 = [] spawn {
                    unit1 sidechat "Coolguy One , this is Coolguy Base. Any activity in the village?";
                    sleep 5;
                    unit2 sidechat "Coolguy Base, this is Coolguy One. Everything's cool in the village, over.";
    };
    In fact I don't really see the point of the module now. It's only useful if you don't know about the chat commands, unless there's some benefit I'm missing. You can sync more than one message to the trigger but you can't add a delay. If you could set a delay in the module itself then you could queue messages and have a timed exchange of text, but as it stands you would need to have multiple triggers, or the messages all show at once.

    Also, using "Objects in synchronized trigger" makes the text appear once for every unit, meaning it gets spammed multiple times. So unless it's just one unit then better to use synched Group or Object instead.
    Last edited by 2nd Ranger; Sep 14 2013 at 11:30.
    empty all your clips at their locations

    Vote!
    http://feedback.arma3.com/view.php?id=9341 - Random placement of units and waypoints does not work near buildings
    http://feedback.arma3.com/view.php?id=17665 - Backpacks can't be placed accurately in editor
    http://feedback.arma3.com/view.php?id=15249 - Add scripting command to disable certain stances

  7. #7
    Sergeant Major IndeedPete's Avatar
    Join Date
    Jun 14 2009
    Location
    Niedersachsen, Germany
    Posts
    1,878
    I was also wondering what the module does but from how it sounds, it's not really useful for more than "Hey, go there and kill everyone, out." I made up my own script for generating simple conversations (without voiceacting at this point).

    radio.sqf:
    Code:
    _speaker = _this select 0; 
    _sentence = _this select 1;
    _wichChat = _this select 2; // 0 - SideChat, 1 - GroupChat, 2 - VehicleChat, 3 - titletext, 4 - commandChat, 5 - globalChat
    		
    _x = 0.1;
    _len = count (toArray _sentence);
    
    private ["_speaker", "_sentence"];
    switch (_wichChat) do {
    	case 0: {_speaker sideChat _sentence};
    	case 1: {_speaker groupChat _sentence};
    	case 2: {_speaker vehicleChat _sentence};
    	case 3: {titletext [format ["%1", name _speaker] + ": """ + _sentence + """","PLAIN DOWN"]};
    	case 4: {_speaker commandChat _sentence};
    	case 5: {_speaker globalChat _sentence};
    	default {hint "nope"};
    };
    
    sleep (_len * _x);
    true;
    Then compile it somewhere in init.sqf:
    Code:
    IP_RADIO = compile (preprocessFileLineNumbers "scripts\radio.sqf");
    And you can use it in your missions to create small conversations:
    Code:
    [gomez_g, "Templar to White King. We're at Point Acre, come in, over.", 0] call IP_RADIO;
    [hackett, "Templar, this is White King. Understood, supply drop on standby, callsign 'Archangel', over.", 0] call IP_RADIO;
    [gomez_g, "Archangel, come in. This is Templar, waiting at Point Acre, over.", 0] call IP_RADIO;
    [IP_ARCHANGEL, "Templar, this is Archangel. Confirmed, entering your airspace now, standby, over.", 0] call IP_RADIO;
    Use the last parameter to specifiy wich chat should be used, so sideChat, groupChat etc. Titletext works fine in cutscenes and the script automatically adds the name of the unit before the text, so e.g. "Guy: 'Hi there!'"
    By changing the value of the _x you can set the factor used to calculate the delay. 0.1 is okay, but with extreme long or extreme short texts it's sometimes a bit to fast or to slow.

  8. #8
    Very Very thanks guys!!! I'm using your tips.

    Best regards.

  9. #9
    IndeedPete, i used ur script, but i cant figure out how to get it work. What do i have to put in the 'On Act' line in my trigger?

    Regards,
    Penny

  10. #10
    Sergeant Major IndeedPete's Avatar
    Join Date
    Jun 14 2009
    Location
    Niedersachsen, Germany
    Posts
    1,878
    I'd recommend to use scriptfiles if you want to display more than one sentence, like in small conversations.

    Create a scriptfile in your mission folder, use notepad.
    conversation1.sqf:
    Code:
    [guy1, "Templar to White King. We're at Point Acre, come in, over.", 0] call IP_RADIO;
    [guy2, "Templar, this is White King. Understood, supply drop on standby, callsign 'Archangel', over.", 0] call IP_RADIO;
    Then call this script somewhere, e.g. by trigger. On Act:
    Code:
    nul = [] execVM "conversation1.sqf"

Similar Threads

  1. Radio Chat Bottom Left
    By aereo in forum ARMA 2 & OA : MISSIONS - Editing & Scripting
    Replies: 4
    Last Post: Apr 25 2012, 20:10
  2. Radio chat, custom name for HQ?
    By Cyper in forum ARMA - MISSION EDITING & SCRIPTING
    Replies: 7
    Last Post: Dec 16 2011, 17:48
  3. Secops AI radio chat minor issue.
    By CuteQA in forum ARMA 2 & OA - GENERAL
    Replies: 4
    Last Post: Jul 10 2009, 09:05
  4. Radio Chat in Cutscene ?
    By hit-man in forum ARMA - MISSION EDITING & SCRIPTING
    Replies: 5
    Last Post: Sep 28 2008, 08:33
  5. Radio chat
    By HoboWithAK in forum OFP : MISSION EDITING & SCRIPTING
    Replies: 2
    Last Post: Feb 13 2004, 20:25

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •