Heal pilot before rescue menu is active

[DragonflyFan]

Guys,

I'm very new to scripting but enjoying working on it. I'm having troubles creating my own scripts from scratch but can figure out and modify others with some success.

I'm hoping someone can help me understand and add extra code to the below mission script. It's part of a mission script from Bon's 'TFOR' addon.

I'd like to make it so that the pilot is slightly injured and before the player gets the 'rescue' action menu he first has to heal the pilot.

What do I need to do to get that to work please?

_grp1 = createGroup tfor_friendly_side;
_pilot = _grp1 createUnit [tfor_rescuepilot_pilottype, _pos, [], 0, "FORM"];
_pilot setRank "CAPTAIN";
_pilot setCaptive true;
_pilot allowFleeing 0;
_pilot setVehicleInit "
this addAction ['Rescue','scripts\capture.sqf'];
"; processInitCommands;

[twirly]

Not tested...but give this a shot. Add the lines in RED. You might want to change the damage values.

This will halt execution of whatever script is running (this script) until the pilot is healed! That may not have desirable effects depending on what's next in the script.

_grp1 = createGroup tfor_friendly_side;
_pilot = _grp1 createUnit [tfor_rescuepilot_pilottype, _pos, [], 0, "FORM"];
_pilot setRank "CAPTAIN";
_pilot setCaptive true;
_pilot allowFleeing 0;

_pilot setDamage 0.6;
waituntil {damage _pilot <= 0.1}; 

_pilot setVehicleInit "this addAction ['Rescue','scripts\capture.sqf'];";
processInitCommands;

EDIT: If that's the case.... do it this way....

_grp1 = createGroup tfor_friendly_side;
_pilot = _grp1 createUnit [tfor_rescuepilot_pilottype, _pos, [], 0, "FORM"];
_pilot setRank "CAPTAIN";
_pilot setCaptive true;
_pilot allowFleeing 0;

_pilot setDamage 0.6;

nul = [_pilot] spawn {
	private ["_pilot"];
	_pilot = _this select 0;
	waituntil {sleep 1;damage _pilot <= 0.1};
	_pilot setVehicleInit "this addAction ['Rescue','scripts\capture.sqf'];";
	processInitCommands;

};

//...script carries on here
//...blah...blah...blah

[DragonflyFan]

Hey Twirly, cheers for that. there's a fair bit more in the script that needs to run so I'm guessing I should try your second option.

Thanks heaps, I'll report back what happens.

[twirly]

Yeah mate... try that second option then. What that does is spawn a separate script that will run alongside the calling script. The spawned script will wait until the pilot is healed before he gets the action.