TPW HOUSELIGHTS - automatic house light addon

[Xeno]

Hmm, http://www.kylania.com/ex/?p=26 suggests otherwise, which is why I and many others use if (!isServer) exitWith {}; to make our scripts run on clients but not servers.

if (isDedicated) exitWith {};

and the script will run on clients only. No matter if it is a client playing on a dedicated server or a client in a hosted environment (including the host which is both, client and server, thus isServer is true for the host).

if (!isServer) exitWith is for scripts which should only run on a server (including a host in a hosted environment).

Xeno

[Rockhount]

"[KH]Jman" tested it as the host of a non dedicated server and because that, "!isServer" wasn't true for him.

[tpw]

I'm a bit confused!

Why does if (!isServer) exitWith {} work in SP and MP clients then? I remember being told long ago by someone to always include that code in the head of my scripts to keep them off servers.

Anyway, thanks for trying to enlighten me Rockhount and Xeno. I'll try if (isDedicated) exitWith {};

[Muzzleflash]

I would recommend against starting the script from the init line of a playable (including player) unit for a MP mission. Pretty sure that that the init line is not run unless somebody actually choses (jip or not) the specific unit which has the init line.

There is no real need for the server to create the lights and manage it for all players. Just create all the lights locally for each player. If the algorithm does not depend on random elements then the result would be the same. Even if it does it probably doesn't matter. A lot of things isn't synced entirely in Arma. I think for instances that dead bodies may lie in different postures for each player in MP. I would do as Xeno suggests running the script on all client machines and create the lights locally for each player, starting the script for all in init.sqf or something like that.

[tpw]

Ok, so I've been hard at work thinking and refining this thing. Here's v1.03:

• Wrote my own flickering routine which hopefully achieves an approximation of Rydygier's, but with less calculation.
• Wrote a flexible light-type system. You can add (or remove) as many light-types as you like, each with configurable colour, brightness and flickering.
• Changed the code regarding (not) executing on dedi servers.

It should run on MP but each player will see different lights due to the randomisation. The CPU and network overhead to synchronise these visuals would be pretty high, and beyond my shit coding abilities.

I will put up an addon version shortly.

Thanks again for the input everyone!

Spoiler:

show spoiler

if (isDedicated) exitWith {}; //This script won't run on dedicated servers (Thanks Xeno)

/*
TPW HOUSELIGHTS v 1.03
This script causes flickering lights to automatically come on in enterable buildings around the player. It will work on any map with ALICE2 compatible enterable buildings, and will simply ignore unenterable ALICE buildings.
Please feel free to modify and improve this script, on the proviso that you post your improvements for others to benefit from.
Thanks:
* CarlGustaffa for the azimuth code
* Rydygier for the inspiration for the flickering code
* RogueTrooper for the improved code for determining enterable buildings

TPW 20120519
*/  

///////////
//VARIABLES
///////////
//Distance player has to move for houses to be rescanned. Player must move greater than this distance to rescan houses.
_movedistance = 50;

//Distance around player to scan for houses to light. There's no point specifying a really large value since the engine won't reliably display lights past 100m or so. 
_housedistance = 100; 

//Percentage of houses to receive lights
_houseperc = 100; 

/*ARRAY OF LIGHT VALUES
You can add or remove lights to taste.
Each individual light array consists of:
[red,green,blue,maximum brightness,minimum brightness,%chance of flickering,%brightness to flicker]
red,green,blue,max and min are all in the range 0 - 255
Flickering %chance and %brightness are in the range 0-100
Flickering uses CPU, so if you want none, set all %chance of flickering values to 0. 
*/

_lightsarray = [
[255,127,24,40,20,100,10],//warm yellow/orange (candle or fire)
[255,200,100,40,20,80,5], //yellow/white (incandesecent)
[100,200,255,40,20,100,10]]; //Blue/white (television or fluorescent

//////////////////////////////////////////
//PROCESS LIGHT ARRAYS INTO USEABLE VALUES
//////////////////////////////////////////
_proclightsarray = [];
{
_red = _x select 0; _red = _red /255;
_green = _x select 1; _green = _green/255;
_blue = _x select 2; _blue = _blue/255;
_max = _x select 3;
_min = _x select 4;
_flperc = _x select 5;
_flvar = _x select 6; _flvar = _flvar/100;
_proclight = [_red,_green,_blue,_max,_min,_flperc,_flvar];
_proclightsarray = _proclightsarray + [_proclight];
} foreach _lightsarray;

//////////////////
//FLICKER FUNCTION
//////////////////
tpw_flicker = call compile format ["%1","{
_lt0 = _this select 0;
_br = _this select 1;
_fv = _this select 2;

_rng = _br * _fv;
_brmax = (_br + _rng);
_brmin = (_br - _rng);
_op = 1;
_inc = _rng/(random 10); 
_slp = random 0.1;
_br2 = _br;
while {not (isNull _lt0)} do
        {
_br2 = _br2 + (_op * _inc);    
_lt0 setLightBrightness _br2; 
if (_br2 > _brmax) then {_op = -1;_brmax = _br + (random _rng);_slp = random 0.2;_inc = _rng/((random 10) + 1);}; 
if (_br2 < _brmin) then {_op = 1;_brmin = _br - (random _rng);_slp = random 0.2;_inc = _rng/((random 10) + 1);};
sleep _slp;
        };
    };"
];

////////////
//MAIN LOOP
////////////
// Initial dummy player position
_lastpos = [0,0,0];

while {true} do 
{

//Only recompute houses to light if player has moved > set distsance
if (player distance _lastpos > _movedistance) then 
    {
//GET ANGLE OF SUN - ADAPTED FROM CARLGUSTAFFA
_lat = -1 * getNumber(configFile >> "CfgWorlds" >> worldName >> "latitude"); 
_day = 360 * (dateToNumber date); 
_hour = (daytime / 24) * 360; 
_sunangle = ((12 * cos(_day) - 78) * cos(_lat) * cos(_hour)) - (24 * sin(_lat) * cos(_day));     

//Recalculate player's position
_lastpos = (position player);

//Only bother if it's dark
if (_sunangle < 0) then 
        {
// Delete lights from previously lit houses        
{deletevehicle _x;} foreach tpw_lithouses; tpw_lithouses = []; 
        
//Find houses within set distance of player        
_houses = nearestObjects [getpos player, ["House"], _housedistance];
            {
//ONLY THE CHOSEN PERCENTAGE OF ENTERABLE HOUSES WITH MULTIPLE BUILDINGPOSITIONS  WILL ACTUALLY LIGHT UP
if ((((_x buildingpos 0) select 0) != 0) and ((random 100) < _houseperc)) then 
                {
_pos = getpos _x;
_lightnum = floor (random (count _proclightsarray));_light = _proclightsarray select _lightnum; //Select light type
_r = _light select 0;_g = _light select 1;_b = _light select 2;_col = [_r,_g,_b]; //Light colour values
_max = _light select 3;_min = _light select 4;//Light brightness range
_flperc = _light select 5;_flvar = _light select 6;//Light flickering parameters
_br = 0.1 * ((_min + (random (_max - _min)))/255); //Random brightness between specified range    
_lp = "#lightpoint" createVehicleLocal _pos; //Create light
_lp setLightBrightness _br; // Set its brightness
_lp setLightColor _col; // Set its colour
_lp lightAttachObject [_x, [random 2,random 2,1]]; // place it at a random position within house 
if ((random 100) < _flperc) then {[_lp,_br,_flvar] spawn tpw_flicker}; // Set appropriate flicker for light type
tpw_lithouses = tpw_lithouses + [_lp]; // Add it to the lit houses array so it can be removed later        
                };
            } foreach _houses;
        };
    };
sleep 10;
}; 

[bigshotking]

v1.03 is erroring out tpw.

Here is a snippet from my .RPT:

File C:\Users\******\Documents\ArmA 2 Other Profiles\*********\mpmissions\********\common\client\ambient_lights.sqf, line 40
Error in expression <20,5], 
_tv = [100,200,255,60,30,100,30]]; 
_ratio = [4,2,1]; 




_lightarray =>
  Error position: <]; 
_ratio = [4,2,1]; 




_lightarray =>
  Error Missing ;

and here as well:

Error in expression <n player);

{deletevehicle _x;} foreach tpw_lithouses; tpw_lithouses = []; 

if >
  Error position: <tpw_lithouses; tpw_lithouses = []; 

if >
  Error Undefined variable in expression: tpw_lithouses
File C:\Users\*******\Documents\ArmA 2 Other Profiles\*******\mpmissions\*******\common\client\ambient_lights.sqf, line 97

EDIT: Error came from taking the code from the first post, the code given in the post above is error free.

[tpw]

Thanks bigshotking. A rogue ] crept in when I was doing the final edit of the script version before uploading it. That's what you get for scripting late at night.

It should work as advertised for you now. The addon version is fine.

Cheers
tpw

v1.03 is erroring out tpw.

Here is a snippet from my .RPT:

File C:\Users\******\Documents\ArmA 2 Other Profiles\*********\mpmissions\********\common\client\ambient_lights.sqf, line 40
Error in expression <20,5], 
_tv = [100,200,255,60,30,100,30]]; 
_ratio = [4,2,1]; 




_lightarray =>
  Error position: <]; 
_ratio = [4,2,1]; 




_lightarray =>
  Error Missing ;

and here as well:

Error in expression <n player);

{deletevehicle _x;} foreach tpw_lithouses; tpw_lithouses = []; 

if >
  Error position: <tpw_lithouses; tpw_lithouses = []; 

if >
  Error Undefined variable in expression: tpw_lithouses
File C:\Users\*******\Documents\ArmA 2 Other Profiles\*******\mpmissions\*******\common\client\ambient_lights.sqf, line 97

EDIT: Error came from taking the code from the first post, the code given in the post above is error free.

[RogueTrooper]

I haven't read the recent pages fully, so please excuse me if it should have been mentioned.
It seems as if the GLOBAL command createvehicle #lightpoint only works locally. The light only shows up where the command has been executed. Concerning randomness (colours and which houses are lit), the server should make globalvariable'd arrays that the clients have to use.

Btw, using totally randomized colours for many houses does NOT look that bad at all (_light setLightColor [random 1,random 1,random1]). This way, Zargabad at night for example with many total-randomized houselights looks nice (some kind of cosy and colourful Orient of auld lang syne).

[McLupo]

Hello tpw,
it is great to see, how a "little thing" is growing up! Now v 1.03
Well done mate and thx to all who help this smart guy!

That´s how com works! Fantastic!
Cheers
McLupo

[domokun]

The link to v1.03 is broken on Armaholic.
Foxhound: could you please fix it?