Markers and JIP persistancy...with CBA_fnc_setMarkerPersistant

[CarlosTex]

Where did you pre placed the marker? On the editor?

psvialli, don't forget that everything that you put in the editor runs again when JIP players connect. So everything goes back to its original position.

save this as "init_createMarkers.sqf";

if (isServer) then {
   // Setup eventHandler
   ["TEX_markers", 
	{ 
	_marker = _this select 0; //String
	_pos = _this select 1; //Array
	_shape = _this select 2; //String
	_type = _this select 3; //String
	_size = _this select 4; //Array 
	_color = _this select 5; //String
	_mkr = createMarker [_marker, _pos];
	_marker setMarkerShape _shape;
	_marker setMarkerType _type;
	_marker setMarkerSize _size;
	_marker setMarkerColor _color;
	}] call CBA_fnc_addEventHandler; //EventHandler	
	
   // Helper function
   TEX_fnc_createMarker = { ["TEX_markers", _this] call CBA_fnc_localEvent }; // no need to broadcast, we're already on the server
} else {
   // Helper function
   TEX_fnc_createMarker = { ["TEX_markers", _this] call CBA_fnc_globalEvent }; // broadcast to execute on server
};

and this in the init.sqf of your mission:

call compile preProcessFileLineNumbers "init_CreateMarkers.sqf";

Then make sure you create the marker ONLY on the server:

if (isServer) then {
["markerxxx", [5835.1426,3076.4465], "ICON", "mil_objective", [0.5,0.5], "ColorRed"] call TEX_fnc_createMarker;
};

And finally one line below make it persistant:

["markerxxx", true] call CBA_fnc_setMarkerPersistent;

[Sickboy]

Nice going there Tex!

Once bug in code:

"markerxxx", [5835.1426,3076.4465], "ICON", "mil_objective", [0.5,0.5], "ColorRed"] call TEX_fnc_createMarker;

lacks initial '[':

["markerxxx", [5835.1426,3076.4465], "ICON", "mil_objective", [0.5,0.5], "ColorRed"] call TEX_fnc_createMarker;

[CarlosTex]

Right i usually make copy and paste errors. Thanks Sickboy.

Sickboy BTW, do you have any idea why AI groups do out of path planning errors in the RPT? I noticed that some of the AI groups in my mission were stopping to a dead halt, and when i checked the RPT's there were out of path planning errors... This is killing me... Those groups are being spawned by BIS_fnc_spawnGroup BTW....

[1PARA{God-Father}]

Many thanks for the Example / explanation however i am still having an issue not sure if it is because it is on a dedi server or because i am using it through an add action ?

my add action calls the script that has this

if (isServer) then {
["rallym", getpos playerss1_object, "ICON", "mil_objective", [0.5,0.5], "ColorRed"] call TEX_fnc_createMarker;
["rallym", true] call CBA_fnc_setMarkerPersistent;
};

When i test on hosted it works but when i try on Dedi it does not even create the marker? is it because of the add action ?

[CarlosTex]

Try this:

[-0, {["rallym", getpos playerss1_object, "ICON", "mil_objective", [0.5,0.5], "ColorRed"] call TEX_fnc_createMarker;
["rallym", true] call CBA_fnc_setMarkerPersistent;}] call CBA_fnc_globalExecute;

Also make sure you have initialised the eventhandler

[Sickboy]

Actually you should just drop the isServer check, because the client is not a server, and the action is triggered on the player's machine.

Additionally, usage of CBA_fnc_globalExecute other than for debugging is not recommended.
In case you need to trigger remote events, better use CBA_fnc_addEventHandler and CBA_fnc_globalEvent,
this only sends parameters over the network, as opposed to globalExecute which also sends the code.

[1PARA{God-Father}]

I just tested it again but using a radio trigger this time and it worked as expected. but when using add action - no go ?!

Ill test it again with the above code , but it looks like it must be the add action ?

[CarlosTex]

What i gave you should work, but it would be better to follow Sickboy's advice. You can also use MP framework for the addaction.