Ai suppression script help

[Orcinus]

Yep I am going to make a version like this as soon as I get home tonight minus the find cover as I don't think it's functional. The skills part should make it so I can bump up ai accuracy and still have some relatively long firefights, but I can understand why it not everyone's cup of tea, which is why the current versions don't have it.

It should be relatively easy to do, as the code required is already written on page 3

I agree, find cover does seem to be broken.

Might be interesting to see what happens with dropping the "courage" factor when units are suppressed (nice would be proportional to # of bullets whizzing past, but that would be too CPU-intensive) - though I'm not at all clear of the relationship between "courage" & "fleeing".

[-Coulum-]

nice would be proportional to # of bullets whizzing past, but that would be too CPU-intensive

Yes and no. It probably wouldn't be to system intensive, but there is a difference between cowardice and common sense. Right now, I see the reaction of the ai to suppression as a common sense reaction rather than one out of fear. But I will make shooting skill decrease by a factor proportional to the unit's courage to represent how men can panic under fire reducing their accuracy.

I could be wrong, but I also believe that a units courage determines how willing he is to advance (don't quote me on that though, I have't actually tested). So ideally, if courage is decreased while under fire, it should be possible to suppress a units movement although I doubt it will be possible to totally pin them.
--edit--

Yep I am going to make a version like this as soon as I get home tonight minus the find cover as I don't think it's functional. The skills part should make it so I can bump up ai accuracy and still have some relatively long firefights, but I can understand why it not everyone's cup of tea, which is why the current versions don't have it.

Sorry, I lied - probably won't get time to work on this until Friday, maybe Thursday.
First post updated

[tpw]

Here's a quick and dirty proof of concept script. If the unit is suppressed by a single bullet, his aiming accuracy and shake values are set to 75% of their original. If suppressed by multiple rounds, they drop to 50%. -Coulum- has a more refined way of changing these parameters, but this should show if the concept is workable. I can't test it at work....

Spoiler:

show spoiler

// ALL INFANTRY UNITS ON MAP WILL DROP IF ANY BULLETS PASS WITHIN 10m
// BULLETS FIRED FROM LESS THAN 20m ARE IGNORED 
// BULLETS FROM SMG AND PISTOLS ARE IGNORED
// Original code idea by -Coulum-
// TPW 20120620 

//Start hint
0 = [] spawn {sleep 3;hintsilent "AI suppress active"; sleep 3; hintsilent ""};

private ["_supnextime","_unit","_bc","_shots","_dist"]; 

//Pistol and SMG  ammo to ignore
tpw_mags =["30rnd_9x19_MP5",
"30rnd_9x19_MP5SD",
"15Rnd_9x19_M9",
"15Rnd_9x19_M9SD",
"7Rnd_45ACP_1911",
"8Rnd_9x18_Makarov",
"8Rnd_9x18_MakarovSD",
"64Rnd_9x19_Bizon",
"64Rnd_9x19_SD_Bizon",
"13Rnd_9mm_SLP",
"17Rnd_9x19_glock17",
"6Rnd_45ACP",
"30Rnd_9x19_UZI",
"30Rnd_9x19_UZI_SD"];

//Main function
tpw_sup =  
{ 
    {
    _unit = _x; 
        if (vehicle _x == _x) then 
        {
        _SupNextTime = _unit getVariable ["SupNextTime", -1]; 
        if (_SupNextTime == -1) then 
            {
            _unit setvariable ["SupAccuracy",_unit skill "aimingAccuracy"];
            _unit setvariable ["SupShake",_unit skill "aimingshake"];
            _unit setVariable ["SupNextTime", diag_tickTime];
            _unit addeventhandler ["Fired",{tpw_fired = _this select 0;tpw_mag = _this select 5; tpw_bullet = _this select 6}];
            };
        if (diag_tickTime >= _SupNextTime) then {_unit setVariable ["Shots", 0]}; 
        _bc = 0;
        if !(isnull tpw_bullet) then 
            {
            _bc = count ((getposatl _unit) nearobjects ["Bulletbase",10])
            };
        if (_bc > 0) then 
            {
            _dist = tpw_fired distance _unit;
            if (_dist > 25) then 
                {
                if !(tpw_mag in tpw_mags) then {
                    _unit setVariable ["SupNextTime", diag_tickTime + 3 + random 5];
                    _shots = _unit getVariable "Shots";
                    _unit setVariable ["Shots", _shots + _bc];
                    }
                }
            };
        _shots = _unit getVariable "Shots";
        _accuracy = _unit getvariable "SupAccuracy";
        _shake = _unit getvariable "SupShake";
        if (_shots == 0) then {_unit setunitpos "auto"};
        if (_shots > 0) then {_unit setunitpos "middle"; _accuracy = _accuracy * 0.75; _shake = _shake * 0.75};
        if (_shots > 5) then {_unit setunitpos "down"; _accuracy = _accuracy * 0.5; _shake = _shake * 0.5};
        _unit setskill ["AimingAccuracy",_accuracy];
        _unit setskill ["AimingShake",_shake];        

               }
    } forEach allunits;
}; 

//Call function using per frame eventhandler so computer doesn't explode
[tpw_sup,0] call cba_fnc_addPerFrameHandler; 

[CameronMcDonald]

You need to cease all gainful employment immediately, tpw, and become a scripting poopsocker/neckbearder ASAP.

[tpw]

You need to cease all gainful employment immediately, tpw, and become a scripting poopsocker/neckbearder ASAP.

Thanks for the high praise! If I don't stop looking at this site when I'm at work, they might cease my gainful employment for me

[-Coulum-]

You need to cease all gainful employment immediately, tpw, and become a scripting poopsocker/neckbearder ASAP.

I concur.

[Mr_Centipede]

I had a thought... I think you guys can combine both the Distance version and the Side version together.

Basically the script should use the distance version in overall, but the side version comes in when trying to alter the skills.
I think this would let the friendly AI to duck when a fire from a SBF team coming from overhead (probably reduce friendly fire a bit) but the skills wont be altered.

Just my 2cents worth

[tpw]

Fantastic idea, I am looking into it right now!

I had a thought... I think you guys can combine both the Distance version and the Side version together.

Basically the script should use the distance version in overall, but the side version comes in when trying to alter the skills.
I think this would let the friendly AI to duck when a fire from a SBF team coming from overhead (probably reduce friendly fire a bit) but the skills wont be altered.

Just my 2cents worth

[Orcinus]

+1, Mr_Centipede

[tpw]

I took time out from my poopsocking to implement Mr_Centipede's suggestion and so far it seems to be working OK. Please try it out.

I also spent a bit of time trying to optimise the code a bit. There's lots of nested if statements, which look ugly but should speed things up thusly:

For each unit on map -->
if unit is not in a vehicle -->
if there is an active bullet -->
if the bullet count around unit is greater than 0 -->
if the distance of the shooter to the unit is greater than 25m -->
if the shooter's mag is not pistol or SMG -->
if shooter is enemy then unit drops and skills are reduced
else shooter is same side so unit drops but retains skills

So most of the time the script is actually only really checking if the unit is not in a vehicle and if there are any bullets being shot, which is not draining the CPU terribly. Only as each nested requirement is met does the script delve deeper and apply more calculations.

For this proof of principle I only bothered changing a unit's overall skill, not the various components individually.

Script: Spoiler:

show spoiler

// ALL INFANTRY UNITS ON MAP WILL REACT IF ANY BULLETS PASS WITHIN 10m
// BULLETS FIRED FROM LESS THAN 25m ARE IGNORED 
// BULLETS FROM SMG AND PISTOLS ARE IGNORED
// BULLETS FROM OWN SIDE CAUSE UNIT TO KNEEL/CROUCH
// BULLETS FROM ENEMY SIDE CAUSE UNIT TO KNEEL/DROP, AND TEMPORARY DECREASE IN SKILL

// Original code idea by -Coulum-
// TPW 20120620 

//Start hint
0 = [] spawn {sleep 3;hintsilent "AI suppress active"; sleep 3; hintsilent ""};

private ["_supnextime","_unit","_bc","_shots","_skill"]; 

//Pistol and SMG  ammo to ignore
tpw_mags =["30rnd_9x19_MP5",
"30rnd_9x19_MP5SD",
"15Rnd_9x19_M9",
"15Rnd_9x19_M9SD",
"7Rnd_45ACP_1911",
"8Rnd_9x18_Makarov",
"8Rnd_9x18_MakarovSD",
"64Rnd_9x19_Bizon",
"64Rnd_9x19_SD_Bizon",
"13Rnd_9mm_SLP",
"17Rnd_9x19_glock17",
"6Rnd_45ACP",
"30Rnd_9x19_UZI",
"30Rnd_9x19_UZI_SD"];

//Main function
tpw_sup =  
{ 
    {
    _unit = _x; 
        if (vehicle _x == _x) then 
        {
        _SupNextTime = _unit getVariable ["SupNextTime", -1]; 
        if (_SupNextTime == -1) then 
            {
            _unit setVariable ["SupNextTime", diag_tickTime];
            _unit setVariable ["SupSkill", skill _unit];
            _unit setvariable ["SupSide", side _unit]; 
            _unit addeventhandler ["Fired",{tpw_fired = _this select 0;tpw_mag = _this select 5; tpw_bullet = _this select 6}];
            };
        if (diag_tickTime >= _SupNextTime) then 
            {
            _unit setVariable ["SupShots", 0];
            _unit setunitpos "auto";
            _unit setskill (_unit getvariable "SupSkill");
            };
        if !(isnull tpw_bullet) then 
            {
            _bc = count ((getposatl _unit) nearobjects ["Bulletbase",10]);
            if (_bc > 0) then 
                {
                if ((tpw_fired distance _unit) > 25) then 
                    {
                    if !(tpw_mag in tpw_mags) then 
                        {
                        _unit setVariable ["SupNextTime", diag_tickTime + 3 + random 5];
                        _shots = _unit getVariable "SupShots";
                        _unit setVariable ["SupShots", _shots + _bc];
                        _shots = _unit getVariable "SupShots";
                        _skill = _unit getVariable "SupSkill";                
                        if (side tpw_fired != _unit getVariable "SupSide") then 
                            {
                            if (_shots > 0) then {_unit setunitpos "middle"; _unit setskill _skill * 0.8};
                            if (_shots > 5) then {_unit setunitpos "down"; _unit setskill _skill * 0.6};
                            } 
                            else
                            {
                            if (_shots > 0) then {_unit setunitpos "middle"};
                            };
                        };
                    };
                
                };
            };
        }; 
    } forEach allunits;
};

//Call function using per frame eventhandler so computer doesn't explode
[tpw_sup,0] call cba_fnc_addPerFrameHandler;