Issue with using "getDir" on mountable weapons

[Rumsfield]

I am trying to capture the direction(azimuth) of the weapon a player is mounted to, such as an M2 machine gun, TOW tripod, mortar, etc.

The problem is that as soon as I mount the weapon, the "getDir" command seems to fail/stop working. Here is my code:

_RunLoop = true;
While {_RunLoop} do 
{
_deg = getDir (vehicle player);
hintSilent format ["Degrees: %1", _deg];
};

Does anyone know what is wrong? Thanks!

[Das Attorney]

// find array of weapons in the static gun

_weapons = getArray (configFile >> "CfgVehicles" >> typeOf (vehicle player) >> "Turrets" >> "MainTurret" >> "weapons");

// select main gun

_weap = _weapons select 0;

// return direction in x,y,z format

_dir_array = (vehicle player) weaponDirection _weap;

// convert to degrees

_dir_degrees = (_dir_array select 0) atan2 (_dir_array select 1);

// convert to 360 deg format

if (_dir_degrees < 0) then {_new_degrees = (_dir_degrees + 360)} else {_new_degrees = _dir_degrees};

// test with sidechat

player sideChat format["new deg %1", _new_degrees]; 

[Rumsfield]

Thanks Das Attorney!

Your code works great, except that 180 degrees to 360 was still displaying a negative number, so I just changed your code:

// convert to 360 deg format 

if (_dir_degrees < 0) then {_new_degrees = (_dir_degrees + 360)} else {_new_degrees = _dir_degrees};

To this:

If (_dir_degrees < 0) Then 
   {
	_dir_degrees = _dir_degrees + 360;
   };

Now it works perfect. Danke schön!